home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO050.dsk
/
BUD.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
4KB
|
121 lines
15 D$ = CHR$(4)
20 PRINT D$;"PR#3"
25 PRINT
100 K = 0:Q = 0
2000 GOTO 4000
2200 REM READ TIME
2205 IF FC = 1 THEN TM$ = "": RETURN
2210 PRINT D$;"IN#4": PRINT D$;"PR#4"
2220 INPUT ":";CK$
2230 PRINT D$;"IN#0": PRINT D$;"PR#0"
2240 PRINT D$;"PR#3"
2260 TM$ = MID$ (CK$,12,2) +":" + MID$ (CK$,15,2)
2270 X = VAL( MID$ (CK$,12,2))
2280 IF X <12 THEN TM$ = TM$ +" A.M.": RETURN
2290 IF X <13 THEN TM$ = TM$ +" P.M.": RETURN
2300 X = X -12:X$ = STR$(X):TM$ = X$ + RIGHT$(TM$,3) +" P.M."
2310 RETURN
4000 REM BUDGETS
4010 GOSUB 2200
4020 HOME
4030 HTAB 33: VTAB 1: PRINT "BUDGETS SECTION"
4040 HTAB 28: PRINT "========================="
4050 HTAB 5: VTAB 5: PRINT "ENTER THE CATEGORY OF INTEREST, <RTN> TO SEE LIST, OR <ESC> FOR MAIN MENU""
4080 HTAB 69: VTAB 23: PRINT TM$
6000 REM BUDGETS
6010 IN$ = ""
6020 HTAB 35 +K: VTAB 8: PRINT IN$;
6030 GET X$: IF X$ < > CHR$(13) THEN IN$ = IN$ +X$: GOTO 6070
6040 GOTO 9000
6050 HTAB 35: VTAB 8: PRINT IN$: GOTO 6500
6060 NEXT
6070 IF X$ = CHR$(27) THEN 40000
6080 FOR I = 1 TO 40
6090 IF LEN(CG$(I)) <1 THEN 6120
6100 IF IN$ = LEFT$(CG$(I), LEN(IN$)) THEN K = K +1:Z$ = CG$(I):Q = I
6110 NEXT
6120 IF K = 1 THEN K = 0:IN$ = Z$: GOTO 6050
6130 IF K = 0 THEN 6000
6140 K = 0: GOTO 6020
6500 IF VAL(BG$(Q)) = 0 THEN BG$(Q) = "0.00"
6510 HTAB 16: VTAB 18: PRINT "YOU HAVE BUDGETED $";BG$(Q);" FOR ";CG$(Q);" THIS YEAR"
6520 HTAB 1: VTAB 20: PRINT "YOU MAY EDI<T> THIS, <V>IEW YOUR DEBITS TO THIS CATEGORY, OR GO TO B<U>DGET MENU"
6530 HTAB 40: VTAB 22: GET X$
6540 IF X$ = "U" OR X$ = "u" THEN Q = 0: GOTO 4000
6550 IF X$ = "T" OR X$ = "t" THEN 10000
6560 IF X$ = "V" OR X$ = "v" THEN 15000
6570 IF X$ < >"V" THEN 6510
9000 REM PRINT CATEGORY LIST
9010 HOME
9020 HTAB 31: VTAB 1: PRINT "---CATEGORY LIST---"
9030 VTAB 3
9040 FOR I = 1 TO 20
9050 IF LEN(CG$(I)) <1 THEN 9140
9060 PRINT CG$(I)
9070 NEXT
9080 VTAB 3
9090 FOR I = 21 TO 40
9100 IF LEN(CG$(I)) <1 THEN 9140
9110 HTAB 40
9120 PRINT CG$(I)
9130 NEXT
9140 HTAB 28: VTAB 23: PRINT "PRESS ANY KEY TO CONTINUE"
9150 GET X$
9160 GOTO 4000
10000 REM EDIT
10010 HOME
10020 HTAB 16: VTAB 2
10030 PRINT "YOU HAVE BUDGETED $";BG$(Q);" FOR ";CG$(Q);" THIS YEAR"
10040 HTAB 24: VTAB 5
10050 PRINT "ENTER THE NEW AMOUNT HERE $";
10055 INPUT "";Z$
10060 IF VAL(Z$) <0 THEN Z$ = Z$ * -1
10070 J = INT( VAL(Z$) +.001):BG$(Q) = STR$(J)
10080 HTAB 6: VTAB 10
10090 PRINT "DO YOU WISH TO <`>ENTER $";BG$(Q);" AS NEW BUDGET AMOUNT FOR ";CG$(Q)
10100 HTAB 27: VTAB 11
10110 PRINT "OR RETURN TO B<U>DGET MENU?"
10120 HTAB 40: VTAB 13: GET X$
10130 IF X$ = "U" OR X$ = "u" THEN Q = 0: GOTO 4000
10140 IF X$ = "`" OR X$ = "~" THEN : GOTO 20000
10150 IF X$ < >"`" THEN 10000
15000 REM VIEW CATEGORY DEBITS
15010 BF = 1:YY$ = CG$(Q)
15015 HOME
15020 PRINT D$;"CHAIN /RAM/RPT,@25500"
18000 REM RETURN FROM REPORTS
18010 HOME
18020 PRINT
18025 IF PF = 1 THEN PRINT D$;"PR#1"
18027 PRINT : PRINT
18030 HTAB 16: VTAB 3: PRINT "YOU HAVE BUDGETED $";BG$(Q);" FOR ";CG$(Q);" THIS YEAR"
18037 PRINT
18040 HTAB 26: VTAB 5: PRINT "YOU HAVE SPENT $";TL$
18050 X = VAL(BG$(Q)) - VAL(TL$): IF X <0 THEN NX = X:X = X * -1
18060 J = X *100:Z$ = STR$( INT(J +.01)): IF LEN(Z$) = 1 THEN Z$ = "0" +Z$
18070 Z$ = STR$( INT(X +.001)) +"." + RIGHT$(Z$,2)
18080 IF NX <0 THEN 18200
18085 PRINT
18090 HTAB 22: VTAB 9: PRINT "YOU HAVE $";Z$;" LEFT IN YOUR BUDGET"
18095 IF PF = 1 THEN PF = 0: PRINT D$;"PR#0"
18100 HTAB 15: VTAB 20: PRINT "DO YOU WISH TO GO TO B<U>DGET MENU OR <M>AIN MENU?"
18110 HTAB 40: VTAB 22: GET X$
18120 IF X$ = "M" OR X$ = "m" THEN Q = 0: GOTO 40000
18130 IF X$ = "U" OR X$ = "u" THEN Q = 0: GOTO 4000
18140 IF X$ < >"u" THEN 18000
18150 PRINT
18200 HTAB 20: VTAB 9: PRINT "YOU HAVE OVERSPENT $";Z$;" IN THIS BUDGET"
18205 IF PF = 1 THEN PF = 0: PRINT D$;"PR#0"
18210 NX = 0
18220 GOTO 18100
20000 REM SAVE CATEGORIES
20010 PRINT D$;"OPEN /RAM/CAT.DATA,L$20"
20030 PRINT D$;"WRITE /RAM/CAT.DATA,R";Q
20040 CG$ = CG$(Q)
20050 PRINT CG$
20060 BG$ = BG$(Q)
20070 PRINT BG$
20090 PRINT D$;"CLOSE /RAM/CAT.DATA"
20100 Q = 0: GOTO 4000
40000 PRINT D$;"CHAIN /RAM/CW,@4005"
60000 END